//Array test (fast version)
//Code by Alex Zolotov (2007) nightradio@gmail.com

load_music( "music.xm" )

o = #003050
logo = "
.o...ooo...o.
..o..o.o..o..
...ooooooo...
...ooooooo...
.ooooooooooo.
.o.ooooooo.o.
oo.........oo
+
.o...ooo...o.
..o..o.o..o..
...ooo.ooo...
...ooooooo...
.ooooooooooo.
.o.ooooooo.o.
oo.........oo
"
make_pixi( logo )

command_line =       "PiXelize it_+PiXelize it_+PiXelize it_+PiXelize it+PiXelize it+PiXelize it+PiXelize it+PiXelize it_+PiXelize it"
command_line_color = "111111111111"
make_ascii_pixi( command_line, command_line_color )

start_timer( 0 )
items = 8
x = new_array( items )
y = new_array( items )
d = new_array( items )

a = 0
init_loop:
x[ a ] = ( rand & 127 ) - 64
y[ a ] = ( rand & 127 ) - 64
d[ a ] = 1 + ( rand & 3 )
a + 1
if a < items { go init_loop }

vol = 0
music_volume( vol )
play_music

start:
transp( 256 )
clear( WHITE )

	//Write random colors to the screen:
	scr = 0
	a = 0
	ss = get_pixi_xsize * get_pixi_ysize
	sloop:
	scr[ a ] = get_color( rand & 255, 255, 255 )
	a + 3
	if a < ss { go sloop }

pixi( command_line, -get_pixi_xsize/2 + 52, -72, 1, 0 )

transp( 160 )

//Draw array of logos:
a = 0
loop2:
x[ a ] = x[ a ] + d[ a ]
if x[ a ] > get_pixi_xsize( 0 ) / 2 { d[ a ] = -d[ a ] }
if x[ a ] < -(get_pixi_xsize( 0 ) / 2) { d[ a ] = -d[ a ] }
yy = ccos( get_timer( 0 ) / 16 + y[ a ] ) 
if yy < 0 { yy = -yy }
yy = 80 - yy
pixi( logo, x[ a ], yy, 2, ccos( get_timer( 0 ) / 16 + y[ a ] ) )
print( "$a", x[ a ] + -4, yy + 10 )
a + 1
if a < items { go loop2 }

vol + 4
if vol > 256 { vol = 256 }
music_volume( vol )

frame( 50 )
go start